Longer backspin with Kontrol S2 MK3?

So, here is the file that you need to replace. It's found here: '…\Native Instruments\Traktor Pro 4\Resources64\qml\CSI\S2MK3\S2MK3Deck.qml'. Before replacing it, make a copy of the whole qml folder for safety.

This is what i added:

At the top (so that the timers work):

import QtQuick 2.5

Right above the jogwheel wires i added this section:

//-----------------------------------Jogwheel Scratch Triggers------------------------------------//

property bool deckScratching: false

MappingPropertyDescriptor { id: jogScratchProp; path: "mapping.state.deck." + deckIdx + ".jogscratch_value"; type: MappingPropertyDescriptor.Integer; value: 0; min: 0; max: 60 }

Wire {
  enabled: module.active && !jogFXEnableProp.value && !jogHoldFXEnableProp.value
  from: "%surface%.jogwheel.touch";
  to: ButtonScriptAdapter {
    onPress: {
      if (deckPlaying) {
        deckScratching = true
        deckPlayingProp.value = false
        jogScratchProp.value = 20
      }
    }
    onRelease: {
      if ( deckScratching && jogScratchProp.value < 20 ) {
        deckScratching = false
        deckPlayingProp.value = true
        jogScratchProp.value = 0
      }
    }
  }
}

Wire { enabled: module.active && deckScratching && !jogFXEnableProp.value && !jogHoldFXEnableProp.value;
  from: "%surface%.jogwheel.rotation"; 
  to: EncoderScriptAdapter {
    onIncrement: { jogScratchProp.value=jogScratchProp.value +3 }
    onDecrement: { jogScratchProp.value=jogScratchProp.value +20 }
  }
}

Timer {
  id: scratchSpinTimer
  interval: 8
  repeat: true
  running: deckScratching && jogScratchProp.value > 0
  onTriggered: {
    jogScratchProp.value = jogScratchProp.value - 10;
    if ( deckScratching && jogTouchOnProp.value && jogScratchProp.value < 20 ) {
      jogScratchProp.value = jogScratchProp.value + 10;
    }
    else if ( deckScratching && !jogTouchOnProp.value && jogScratchProp.value < 10 ) {
      deckScratching = false;
      deckPlayingProp.value = true;
      jogScratchProp.value = 0;
    }
  }
}

Wire {
  enabled: module.active;
  from: "%surface%.play";
  to: ButtonScriptAdapter {
    brightness: scratchBlinkTimer.blink ? 0.0 : (deckScratching || deckPlaying) ? 1.0 : 0.0;
    onRelease: {
      if ( deckScratching ) {
        deckScratching = false
        deckPlayingProp.value = false
        jogScratchProp.value = 0
      }
    }
  }
}

Timer {
  id: scratchBlinkTimer
  property bool  blink: false
  interval: 250
  repeat: true
  running: deckScratching
  onTriggered: {
    blink = !blink;
  }
  onRunningChanged: {
    blink = running;
  }
}

You can adjust the scratch length in the ButtonScriptAdapter of the touch wire. This is the value:

jogScratchProp.value = 20

It can go as high as 60.

Note: when scratching, the PLAY state of the deck is temporarily turned off, which may be important if it is the tempo master.

Please test if this works and if it is sufficient for your needs. :)