MX2 qml MODS discussion

This thread is for discussing qml mods for the MX2.

I'll edit this post to list and directly link to different mods listed in this thread in the future and start in the next post with a sample mod.

Grid Adjust MOD: adds x2 and /2 BPM function to SHIFT+SYNC/MASTER button. DIRECT LINK
Stem FX Send Mod: Adds more stem controls when holding PadModeSTEM button. DIRECT LINK

Find more posts tagged with

Traktor Pro 4

MX2

Comments

Sûlherokhh

— GridAdjust BPM double/half commands MOD —

As requested, here is a sample mod that adds Grid BPM double/half commands.

The effect will be that when you hold down SHIFT button, MASTER and SYNC buttons will function as grid multipliers.

Original code of 'qml/CSI/MX2Deck.qml', line 120++

// Master + Sync
Wire { from: "%surface_prefix%.sync.color"; to: "transport.sync.color" }
Wire { from: "%surface_prefix%.sync.brightness"; to: "transport.sync.brightness" }
Wire { from: "%surface_prefix%.master.color"; to: "transport.master.color" }
Wire { from: "%surface_prefix%.master.brightness"; to: "transport.master.brightness" }

AppProperty { id: syncProp; path: "app.traktor.decks." + module.index + ".sync.enabled" }
AppProperty { id: masterProp; path: "app.traktor.decks." + module.index + ".set_as_master" }

Wire
{
  from: "%surface_prefix%.sync"
  to: ButtonScriptAdapter {
    id: syncButton
    property bool engaged: false
    onPress: {
      if (masterButton.engaged)
     {
        masterButton.engaged = false;
        tempoControl.reset();
      }
      else
     {
        syncButton.engaged = true;
      }
    }
    onRelease: {
      if (syncButton.engaged)
      {
        syncProp.value = !syncProp.value;
      }
    }
    output: false
  }
}

Wire
{
  from: "%surface_prefix%.master"
  to: ButtonScriptAdapter {
    id: masterButton
    property bool engaged: false
    onPress: {
      if (syncButton.engaged)
      {
        syncButton.engaged = false;
        tempoControl.reset();
      }
      else 
     {
        masterButton.engaged = true;
      }
    }
    onRelease: {
      if (masterButton.engaged)
      { 
         masterProp.value = true;
      }
    }
    output: false
  }
}

I am now adding 'enabled' lines to constrain SYNC and MASTER button I/O to the nonSHIFT layer as well as adding the new commands using the SHIFT layer (with capital letter comments at the end of all modified or new lines to show the difference).

The result now looks like this:

// Master + Sync
Wire { from: "%surface_prefix%.sync.color"; to: "transport.sync.color"; enabled: !module.shift } // MODIFIED
Wire { from: "%surface_prefix%.sync.brightness"; to: "transport.sync.brightness"; enabled: !module.shift } // MODIFIED
Wire { from: "%surface_prefix%.master.color"; to: "transport.master.color"; enabled: !module.shift } // MODIFIED
Wire { from: "%surface_prefix%.master.brightness"; to: "transport.master.brightness"; enabled: !module.shift } // MODIFIED

AppProperty { id: syncProp; path: "app.traktor.decks." + module.index + ".sync.enabled" }
AppProperty { id: masterProp; path: "app.traktor.decks." + module.index + ".set_as_master" }

Wire
{
  enabled: !module.shift // MODIFIED
  from: "%surface_prefix%.sync"
  to: ButtonScriptAdapter {
    id: syncButton
    property bool engaged: false
    onPress: {
      if (masterButton.engaged) 
      { 
         masterButton.engaged = false; 
         tempoControl.reset(); 
       } 
       else 
      {
        syncButton.engaged = true;
      }
    } 
    onRelease: {
      if (syncButton.engaged) 
     { 
       syncProp.value = !syncProp.value; 
     }
    }
    output: false
  }
}


Wire
{
  enabled: !module.shift // MODIFIED
  from: "%surface_prefix%.master"
  to: ButtonScriptAdapter {
    id: masterButton
    property bool engaged: false
    onPress: {
      if (syncButton.engaged)
      {
        syncButton.engaged = false;
        tempoControl.reset();
      }
      else 
     {
        masterButton.engaged = true;
      }
    }
    onRelease: {
      if (masterButton.engaged)
      { 
         masterProp.value = true;
      }
    }
    output: false
  }
}

// ADDED COMMANDS
Wire { enabled: module.shift; from: "%surface_prefix%.master"; to: TriggerPropertyAdapter { path: "app.traktor.decks." + module.index + ".track.grid.half_bpm" } } // NEW
Wire { enabled: module.shift; from: "%surface_prefix%.sync"; to: TriggerPropertyAdapter { path: "app.traktor.decks." + module.index + ".track.grid.double_bpm" } } // NEW

yannickjeh

Works like a charm, thank you very much for this! 😁

Sûlherokhh

You can easily switch the functions around, if you want SYNC to halve and MASTER to double the BPM, like this:

Wire { enabled: module.shift; from: "%surface_prefix%.master"; to: TriggerPropertyAdapter { path: "app.traktor.decks." + module.index + ".track.grid.double_bpm" } } // NEW
Wire { enabled: module.shift; from: "%surface_prefix%.sync"; to: TriggerPropertyAdapter { path: "app.traktor.decks." + module.index + ".track.grid.half_bpm" } } // NEW

wate

This modification adds Stems FX Send control while holding Stems Pad mode button + Stem Focus Pad + rotating Right encoder (pressing resets the FX value back to 100). Same functionality as default Stems Volume and Filter control when Stems Pad mode button is held.

Two files need edits: MX2Deck.qml and MX2Stems.qml

———
MX2Deck.qml
———

1. Find the block of property bool declarations near the top (where hotcuesModeHeld is located) in MX2Deck.qml. Add: property bool stemsModeHeld: false

Before:

property bool hotcuesModeHeld: false

After:

property bool hotcuesModeHeld: false
property bool stemsModeHeld: false

———

2. Replace the STEMS button wire in MX2Deck.qml

The original just set pads mode on press. The replacement also tracks whether the button is currently
held down, and turns the LED white while it is.

Find this wire:

Wire {
  enabled: deckTypeProp.value == DeckType.Stem
  from: "%surface_prefix%.stems"
  to: SetPropertyAdapter{ path: module.propertiesPath + ".pads_mode"; value: module.stems; color: Color.Blue }
}

Replace entire block with:

Wire {
  enabled: deckTypeProp.value == DeckType.Stem
  from: "%surface_prefix%.stems"
  to: ButtonScriptAdapter
  {
    onPress:   { padsMode.value = module.stems; stemsModeHeld = true;  }
    onRelease: { stemsModeHeld = false; }
    color:      stemsModeHeld ? Color.White : Color.Blue
    brightness: padsMode.value == module.stems ? onBrightness : dimmedBrightness
  }
}

———

3. Find the MX2Stems { } block in MX2Deck.qml and add one line: stemsHeld: stemsModeHeld

Before:

MX2Stems
{
  ...
  shift: module.shift
}

After:

MX2Stems
{
  ...
  shift: module.shift
  stemsHeld: stemsModeHeld
}

———
MX2Stems.qml
———

4. Near the other property bool declarations at the top of MX2Stems.qml, add one line: property bool stemsHeld: false

Before:

property bool shift: false
property string deckPropertiesPath: ""

After:

property bool shift: false
property bool stemsHeld: false
property string deckPropertiesPath: ""

———

5. In MX2Stems.qml file find this line inside the loop_move/loop_size WiresGroup:

This stops the right encoder from controlling volume/filter at the same time as FX send.

Before:

enabled: !module.shift

After:

enabled: !module.shift && !module.stemsHeld

———

6. In MX2Stems.qml file insert this entire block after the volume/filter WiresGroup and before the lower pads focus section //------------------------- Lower pads to stem focus --------------------------- (the Wire { from: "%surface%.pads.5" lines):

//------- FX send for focused stem — active while stems mode button is held -------

WiresGroup
{
  enabled: module.stemsHeld

  WiresGroup
  {
    enabled: propActiveStem.value == 1
    Wire { from: "%surface%.loop_size";      to: RelativePropertyAdapter { path: "app.traktor.decks." + deckIdx + ".stems.1.fx_send"; step: 0.05; mode: RelativeMode.Stepped } }
    Wire { from: "%surface%.loop_size.push"; to: SetPropertyAdapter      { path: "app.traktor.decks." + deckIdx + ".stems.1.fx_send"; value: 1.0 } }
  }
  WiresGroup
  {
    enabled: propActiveStem.value == 2
    Wire { from: "%surface%.loop_size";      to: RelativePropertyAdapter { path: "app.traktor.decks." + deckIdx + ".stems.2.fx_send"; step: 0.05; mode: RelativeMode.Stepped } }
    Wire { from: "%surface%.loop_size.push"; to: SetPropertyAdapter      { path: "app.traktor.decks." + deckIdx + ".stems.2.fx_send"; value: 1.0 } }
  }
  WiresGroup
  {
    enabled: propActiveStem.value == 3
    Wire { from: "%surface%.loop_size";      to: RelativePropertyAdapter { path: "app.traktor.decks." + deckIdx + ".stems.3.fx_send"; step: 0.05; mode: RelativeMode.Stepped } }
    Wire { from: "%surface%.loop_size.push"; to: SetPropertyAdapter      { path: "app.traktor.decks." + deckIdx + ".stems.3.fx_send"; value: 1.0 } }
  }
  WiresGroup
  {
    enabled: propActiveStem.value == 4
    Wire { from: "%surface%.loop_size";      to: RelativePropertyAdapter { path: "app.traktor.decks." + deckIdx + ".stems.4.fx_send"; step: 0.05; mode: RelativeMode.Stepped } }
    Wire { from: "%surface%.loop_size.push"; to: SetPropertyAdapter      { path: "app.traktor.decks." + deckIdx + ".stems.4.fx_send"; value: 1.0 } }
  }
}

Sûlherokhh

https://community.native-instruments.com/discussion/comment/257459#Comment_257459

Excellent! :)

Quick links

Unanswered questions