Patch samples stop working when zone remapped?

It's very likely that custom scripting for the particular library you've tried to modify already has hardcoded playable ranges, so you moving zones around messes this up.

What you could try doing is use the Remap Keyboard multiscript - with this one you can remap which key plays which other key, for each MIDI channel separately.

I did mention Remap Keyboard, since that one enabled you to remap each and every MIDI channel available in Kontakt. But you do have to remap each channel separately, there are no copy-paste facilities.

You're right, there IS a bug in that multiscript! Well, we need to fix that. Here's a modified version of that script that works properly, plus also adds copy/paste options:

on init
   message("")

   declare const $NUM_CHANNELS := 64
   declare const $KEYMAP_SIZE := 128

   set_script_title("Remap Keyboard")
   set_ui_height(3)

   declare $i
   declare $j
   declare %clipboard[$KEYMAP_SIZE] := (-1)
   declare %keymap[$KEYMAP_SIZE * $NUM_CHANNELS]
   declare !ports[4]
   !ports[0] := "[A] "
   !ports[1] := "[B] "
   !ports[2] := "[C] "
   !ports[3] := "[D] "

   $i := 0
   while ($i < $KEYMAP_SIZE)
      $j := 0
      while ($j < $NUM_CHANNELS)
         %keymap[($KEYMAP_SIZE * $j) + $i] := $i

         inc($j)
      end while

      inc($i)
   end while

   declare ui_table %Remap[128] (1, 1, 127)
   move_control_px(%Remap, 59, 2)
   set_control_par(get_ui_id(%Remap), $CONTROL_PAR_WIDTH, 518)
   set_control_par(get_ui_id(%Remap), $CONTROL_PAR_HEIGHT, 102)

   declare ui_menu $Channel
   move_control_px($Channel, 59, 107)

   $i := 0
   while ($i < $NUM_CHANNELS)
      add_menu_item($Channel,"MIDI Ch: " & !ports[$i / 16] & $i mod 16 + 1,$i)

      inc($i)
   end while

   declare ui_button $MIDISelect
   set_text($MIDISelect, "MIDI Select")
   set_control_par(get_ui_id($MIDISelect), $CONTROL_PAR_TEXT_ALIGNMENT, 1)
   move_control_px($MIDISelect, 149, 107)

   declare ui_value_edit $From (0, 127, $VALUE_EDIT_MODE_NOTE_NAMES)
   move_control_px($From, 239, 107)

   declare ui_value_edit $To (0, 127, $VALUE_EDIT_MODE_NOTE_NAMES)
   move_control_px($To, 330, 107)

   declare ui_menu $Edit
   add_menu_item($Edit, "Edit...", -1)
   add_menu_item($Edit, "--------------------------", -1)
   add_menu_item($Edit, "Copy Mapping", 1)
   add_menu_item($Edit, "Paste Mapping", 2)
   add_menu_item($Edit, "--------------------------", -3)
   add_menu_item($Edit, "Reset Mapping", 3)
   add_menu_item($Edit, "Reset All Mappings", 4)
   move_control_px($Edit, 490, 107)

   set_control_help(%Remap, "Remapping Table: Displays the keyboard mapping of the currently selected <MIDI Channel>.")
   set_control_help($Channel, "MIDI Channel: Selects the MIDI channel for editing the keyboard mapping.")
   set_control_help($MIDISelect, "MIDI Select: Selects the <From Key> based on the incoming MIDI notes over the selected <MIDI Channel>.")
   set_control_help($From, "From Key: Selects which key to remap.")
   set_control_help($To, "To Key: Selects to which key will the <From Key> be remapped.")
   set_control_help($Edit, "Edit Options: Offers copy, paste and reset options for the keyboard mappings.")

   make_persistent($Channel)
   make_persistent(%keymap)

   read_persistent_var($Channel)
   read_persistent_var(%keymap)

   $i := 0
   while ($i < $KEYMAP_SIZE)
      %Remap[$i] := %keymap[($KEYMAP_SIZE * $Channel) + $i]
      inc($i)
   end while

   $From := 60
   $To := %Remap[$From]
end on


on midi_in
   if ($MIDI_COMMAND = $MIDI_COMMAND_NOTE_ON)
      if ($MIDI_CHANNEL = $Channel and $MIDISelect = 1)
         $From := $MIDI_BYTE_1
         $To := %Remap[$MIDI_BYTE_1]
      end if

      set_event_par($EVENT_ID, $EVENT_PAR_MIDI_BYTE_1, %keymap[($KEYMAP_SIZE * $MIDI_CHANNEL) + $MIDI_BYTE_1])
      exit
   end if

   if ($MIDI_COMMAND = $MIDI_COMMAND_NOTE_OFF)
      set_event_par($EVENT_ID, $EVENT_PAR_MIDI_BYTE_1, %keymap[($KEYMAP_SIZE * $MIDI_CHANNEL) + $MIDI_BYTE_1])
      exit
   end if

   if ($MIDI_COMMAND = $MIDI_COMMAND_POLY_AT)
      set_event_par($EVENT_ID, $EVENT_PAR_MIDI_BYTE_1, %keymap[($KEYMAP_SIZE * $MIDI_CHANNEL) + $MIDI_BYTE_1])
      exit
   end if
end on


on ui_control (%Remap)
   $i := 0
   while ($i < $KEYMAP_SIZE)
      %keymap[($KEYMAP_SIZE * $Channel) + $i] := %Remap[$i]
      inc($i)
   end while

   $From := $NI_CONTROL_PAR_IDX
   $To := %Remap[$NI_CONTROL_PAR_IDX]

   set_midi($Channel, $MIDI_COMMAND_CC, 123, 1)
end on

on ui_control ($Channel)
   $i := 0
   while ($i < $KEYMAP_SIZE)
      %Remap[$i] := %keymap[($KEYMAP_SIZE * $Channel) + $i]
      inc($i)
   end while

   $To := %keymap[($KEYMAP_SIZE * $Channel) + $From]
end on

on ui_control ($From)
   $To := %keymap[($KEYMAP_SIZE * $Channel) + $From]
end on

on ui_control ($To)
   %keymap[($KEYMAP_SIZE * $Channel) + $From] := $To
   %Remap[$From] := $To
   set_midi($Channel, $MIDI_COMMAND_CC, 123, 1)
end on

on ui_control ($Edit)
   $Edit := abs($Edit)

   select ($Edit)
      case 1
         $i := 0
         while ($i < $KEYMAP_SIZE)
            %clipboard[$i] := %Remap[$i]
            inc($i)
         end while
      case 2
         if (%clipboard[0] # -1)
            set_midi($Channel, $MIDI_COMMAND_CC, 123, 1)

            $i := 0
            while ($i < $KEYMAP_SIZE)
               %Remap[$i] := %clipboard[$i]
               %keymap[($KEYMAP_SIZE * $Channel) + $i] := %clipboard[$i]
               inc($i)
            end while
         end if
      case 3
         set_midi($Channel, $MIDI_COMMAND_CC, 123, 1)

         $i := 0
         while ($i < $KEYMAP_SIZE)
            %Remap[$i] := $i
            %keymap[($KEYMAP_SIZE * $Channel) + $i] := $i
            inc($i)
         end while
      case 4
         $i := 0
         while ($i < $KEYMAP_SIZE)
            %Remap[$i] := $i

            $j := 0
            while ($j < $NUM_CHANNELS)
               %keymap[($KEYMAP_SIZE * $j) + $i] := $i

               inc($j)
            end while

            if ($i < $NUM_CHANNELS)
               set_midi($i, $MIDI_COMMAND_CC, 123, 1)
            end if

            inc($i)
         end while
   end select

   $Edit := -1
end on